$set noveri
$!
$!# From the MTZ file which is the first file argument, create another with
$!# unique reflections and default free R tags.  Output is to file named by
$!# the second file argument, else input with \`-unique' appended to its
$!# basename. Systematic absences are omitted from the output file unless
$!# the -s switch is specified. If free R tags are already present in
$!# the input file, use the -f switch. The -p option lets you select the
$!# percentage of reflections to be included in a bin, the default is 5%.
$!# The -p option is not needed when -f is specified. The percentage needed
$!# is determined from the input MTZ file.
$!
$! Help section
$if p1 .eqs. "H" then goto HELP
$if p1 .eqs. "-H" then goto HELP
$if p1 .eqs. "" then goto HELP
$goto start
$!
$HELP:
$write sys$output " Usage: uniqueify [-s] [-f <LABEL>] [-p percent] <input file>[.mtz] [<output file>]
$write sys$output "                -unique is appended to the input filename as default"
$write sys$output "  -s            systematic absences are kept (default is to omit)"
$write sys$output "  -p percent    of data is flagged for freeRflag bin, the default is 0.05"
$write sys$output "                this is NOT applicable when using -f option"
$write sys$output "  -f <LABEL>    if input file has freeR flags already assigned"
$write sys$output "                where LABEL is the column label for the FreeR flag"
$write sys$output "   If the label has lower case characters then use $uniqueify -f ""Label"" ... "
$stop
$!
$START:
$sflag = ""
$fflag = "NO"
$free_label = "FreeR_flag"
$percent = "0.05"
$iarg = 1
$ARGS:
$tmp1 = f$extract(0,1,p'iarg')                        ! sort out arguments
$if tmp1 .eqs. "" then goto SKIP1
$if tmp1 .eqs. "-" 
$then
$  if p'iarg' .eqs. "-F" 
$  then 
$    fflag = "YES"
$    iarg = iarg + 1
$    ilen = f$length(p'iarg')
$    free_label = f$extract(0,ilen,p'iarg')
$    iarg = iarg + 1
$    write sys$output ""
$    write/symbol sys$output " *** Input file assumed to have a FreeR flag column; named ",free_label," ***"
$    write sys$output ""
$    goto ARGS
$  endif
$!
$  if p'iarg' .eqs. "-S"
$  then
$    sflag = "SYSABS_KEEP"
$    iarg = iarg + 1
$    write sys$output ""
$    write sys$output " *** Systematic absences will be kept in output MTZ ***"
$    write sys$output ""
$    goto ARGS
$  endif
$!
$  if p'iarg' .eqs. "-P"
$  then
$    iarg = iarg + 1
$    ilen = f$length(p'iarg')
$    percent = f$extract(0,ilen,p'iarg')
$    iarg = iarg + 1
$    goto ARGS
$  endif
$endif
$!
$  ilen = f$length(p'iarg')
$  ifile = f$extract(0,ilen,p'iarg') 
$  iarg = iarg + 1
$  ilen = f$length(p'iarg')
$  ofile = f$extract(0,ilen,p'iarg')
$!
$!
$!
$SKIP1:
$extension = f$parse(ifile,,,"type")             ! check if there is an extension and if file exists
$if extension .eqs. "." 
$then
$  infile := 'ifile'.mtz
$else
$  infile := 'ifile'
$endif 
$iflg = f$search(infile)
$if iflg .eqs. "" 
$then
$  write sys$output " Input file not found"
$  stop
$endif
$!
$if ofile .eqs. "" 
$then
$  ilen = f$length(infile)
$  base = f$extract(0,ilen-4,infile)
$  outfile := 'base'-unique.mtz
$else
$  if f$parse(ofile,,,"type") .nes. ".MTZ" 
$  then
$    outfile := 'ofile'.mtz
$  else
$    outfile := 'ofile'
$  endif
$endif
$!
$write sys$output ""
$write/symbol sys$output " *** Input file is ",infile," ***"
$write/symbol sys$output " *** Output file is ",outfile," ***"
$write sys$output ""
$!
$ass/user 'infile' hklin                         ! get SYMM, CELL, High RESOUTION
$ass ccp4_scr:jnk.log sys$output 
$run cbin:mtzdump
go
$deass sys$output
$!
$a = ""                                          ! get MTZ info. from mtzdump
$minres = ""
$spgrp = ""
$open/read tmpfile ccp4_scr:jnk.log
$READ_LOOP:
$  read/end_of_file=SKIP2/error=SKIP2 tmpfile line
$  if f$extract(0,6,line) .eqs. "* Cell" 
$  then
$    read tmpfile line
$    read tmpfile line
$    a = f$extract(0,8,line)
$    b = f$extract(8,8,line)
$    c = f$extract(16,8,line)
$    alpha = f$extract(24,8,line)
$    beta = f$extract(33,8,line)
$    gamma = f$extract(40,8,line)
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    minres = f$extract(27,9,line)
$    maxres = f$extract(39,9,line)
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    read tmpfile line
$    spgrp = f$extract(15,10,line)
$    goto SKIP2
$  endif
$goto READ_LOOP
$!
$SKIP2:
$close tmpfile
$del/noconf/nolog ccp4_scr:jnk.log.*
$if a .eqs. "" then goto END
$if minres .eqs. "" then goto END
$if spgrp .eqs. "" then goto END
$maxres = f$extract(0,8,maxres)                  ! Make high res. limit just alittle higher to avoid round-up
$!
$!
$open/write unique_com ccp4_scr:temp1.com        ! create COM file for unique
$write unique_com "$unique hklout ccp4_scr:temp1.mtz"
$write/symbol unique_com "SYMM ",spgrp
$write/symbol unique_com "CELL ",a," ",b," ",c," ",alpha," ",beta," ",gamma
$write/symbol unique_com "RESO ",maxres
$write unique_com "LABOUT F=FUNI SIGF=SIGFUNI"
$close unique_com
$write sys$output ""
$write sys$output " *** Output from UNIQUE directed to ccp4_scr:unqueify_uni.log ***"
$write sys$output ""
$@ccp4_scr:temp1.com/output=ccp4_scr:uniqueify_uni.log
$!
$if fflag .eqs. "YES"
$then
$  open/write cad_com ccp4_scr:temp2.com         ! create COM file for cad
$  write/symbol cad_com "$cad hklin2 ccp4_scr:temp1.mtz hklin1 ",infile," hklout ccp4_scr:temp2.mtz"
$  write/symbol cad_com sflag
$  write cad_com "LABIN FILE 1 ALLIN"
$  write cad_com "LABIN FILE 2 ALLIN"
$  write cad_com "END"
$  close cad_com
$  @ccp4_scr:temp2.com
$!
$  open/write freerflag_com ccp4_scr:temp3.com   ! create com for freerflag to extend FREE flags for extra hkl
$  write freerflag_com "$on error then goto err"
$  write freerflag_com "$freerflag hklin ccp4_scr:temp2.mtz hklout ccp4_scr:temp3.mtz"
$  write/symbol freerflag_com "COMPLETE FREE=",free_label
$  write freerflag_com "END"
$  write freerflag_com "$exit"
$  write freerflag_com "$err:"
$  write freerflag_com "$uniqueify -h"
$  write freerflag_com "$stop"
$  close freerflag_com
$  write sys$output ""
$  write sys$output " *** Output from FREERFLAG directed to ccp4_scr:uniqueify_frerf.log ***"
$  @ccp4_scr:temp3.com/output=ccp4_scr:uniqueify_frerf.log
$!
$  write sys$output ""
$  write sys$output " *** Output from MTZUTILS directed to ccp4_scr:uniqueify_mtzu.log ***"
$  write sys$output ""
$  ass ccp4_scr:uniqueify_mtzu.log sys$output
$  ass/user ccp4_scr:temp3.mtz hklin 
$  ass/user 'outfile' hklout
$  mtzutils                                      ! mtzutils to get rid of useless UNIQUE labels, FUNI and SIGFUNI
   EXCLUDE FUNI SIGFUNI
$  deass sys$output
$!
$else
$  write sys$output ""
$  write/symbol sys$output " *** Percentage of reflections per FreeR flag bin is ",percent," ***"
$  write sys$output ""
$!
$  open/write freer_com ccp4_scr:temp2.com       ! Assign FreeR flags to these indices
$  write freer_com "$freerflag hklin ccp4_scr:temp1.mtz hklout ccp4_scr:temp2.mtz"
$  if percent .nes. ""
$  then
$    write/symbol freer_com "FREERFRAC ",percent
$  endif
$  write freer_com "END"
$  close freer_com
$  write sys$output ""
$  write sys$output " *** Output from FREERFLAG directed to ccp4_scr:uniqueify_frerf.log ***"
$  write sys$output ""
$  @ccp4_scr:temp2.com/output=ccp4_scr:uniqueify_frerf.log
$!
$  open/write cad_com ccp4_scr:temp3.com         ! create control file for cad
$  write/symbol cad_com "$cad hklin2 ccp4_scr:temp2.mtz hklin1 ",infile," hklout ccp4_scr:temp3.mtz"
$  write/symbol cad_com sflag
$  write cad_com "LABIN FILE 2 E1=FreeR_flag"
$  write cad_com "LABIN FILE 1 ALLIN"
$  write cad_com "END"
$  close cad_com
$  write sys$output ""
$  write sys$output " *** Output from CAD directed to ccp4_scr:uniqueify_cad.log ***"
$  write sys$output ""
$  @ccp4_scr:temp3.com/output=ccp4_scr:uniqueify_cad.log
$!
$  write sys$output ""
$  write sys$output " *** Output from FREERFLAG directed to ccp4_scr:uniqueify_frerf1.log ***"
$  write sys$output ""
$  ass ccp4_scr:uniqueify_frerf1.log sys$output
$  ass/user ccp4_scr:temp3.mtz hklin             ! make sure all refls. have freeR flag assigned
$  ass/user 'outfile' hklout
$  freerflag
   COMPLETE FREE=FreeR_flag
   END
$  deass sys$output
$endif
$!
$del/noconf/nolog ccp4_scr:temp1.*.*,ccp4_scr:temp2.*.*,ccp4_scr:temp3.*.*
$stop
$END
$write sys$output " Unable to obtain symmetry, cell etc. from MTZ header"
$stop